home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / public / fax / src / util / notify.awk < prev    next >
Text File  |  1994-08-01  |  6KB  |  192 lines
  1. #! /bin/sh
  2. #    $Header: /usr/people/sam/fax/util/RCS/notify.awk,v 1.1 1994/04/06 18:31:43 sam Rel $
  3. #
  4. # FlexFAX Facsimile Software
  5. #
  6. # Copyright (c) 1990, 1991, 1992, 1993, 1994 Sam Leffler
  7. # Copyright (c) 1991, 1992, 1993, 1994 Silicon Graphics, Inc.
  8. # 
  9. # Permission to use, copy, modify, distribute, and sell this software and 
  10. # its documentation for any purpose is hereby granted without fee, provided
  11. # that (i) the above copyright notices and this permission notice appear in
  12. # all copies of the software and related documentation, and (ii) the names of
  13. # Sam Leffler and Silicon Graphics may not be used in any advertising or
  14. # publicity relating to the software without the specific, prior written
  15. # permission of Sam Leffler and Silicon Graphics.
  16. # 
  17. # THE SOFTWARE IS PROVIDED "AS-IS" AND WITHOUT WARRANTY OF ANY KIND, 
  18. # EXPRESS, IMPLIED OR OTHERWISE, INCLUDING WITHOUT LIMITATION, ANY 
  19. # WARRANTY OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.  
  20. # 
  21. # IN NO EVENT SHALL SAM LEFFLER OR SILICON GRAPHICS BE LIABLE FOR
  22. # ANY SPECIAL, INCIDENTAL, INDIRECT OR CONSEQUENTIAL DAMAGES OF ANY KIND,
  23. # OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS,
  24. # WHETHER OR NOT ADVISED OF THE POSSIBILITY OF DAMAGE, AND ON ANY THEORY OF 
  25. # LIABILITY, ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE 
  26. # OF THIS SOFTWARE.
  27. #
  28.  
  29. #
  30. # Awk support program for notify shell script.  This
  31. # stuff is broken out into a separate file to avoid
  32. # overflowing the exec arg list on some systems like SCO.
  33. #
  34.  
  35. #
  36. # Construct a return-to-sender message.
  37. #
  38. func returnToSender()
  39. {
  40.     printf "\n    ---- Unsent job status ----\n\n"
  41.     printf "%11s: %s\n", "Destination", number;
  42.     printf "%11s: %s\n", "Sender", sender;
  43.     printf "%11s: %s\n", "Mailaddr", mailaddr;
  44.     if (modem != "any")
  45.     printf "%11s: %s\n", "Modem", modem;
  46.     printf "%11s: %u (mm)\n", "PageWidth", pagewidth;
  47.     printf "%11s: %.0f (mm)\n", "PageLength", pagelength;
  48.     printf "%11s: %.0f (lpi)\n", "Resolution", resolution;
  49.     printf "%11s: %s\n", "Status", status;
  50.     printf "%11s: %u (consecutive failed calls to destination)\n",
  51.     "Dials", ndials;
  52.     printf "%11s: %u (attempts to send current page)\n",
  53.     "Attempts", ntries;
  54.     printf "%11s: %u (directory of next page to send)\n",
  55.     "Dirnum", dirnum;
  56.     if (nfiles > 0) {
  57.     printf "\n    ---- Unsent files submitted for transmission ----\n\n";
  58.     printf "This archive was created with %s, %s, and %s.\n",
  59.         tar, compressor, encoder;
  60.     printf "The original files can be recovered by applying the following commands:\n";
  61.     printf "\n";
  62.     printf "    %s            # generates rts.%s.Z file\n", decoder, tar;
  63.     printf "    %s rts.%s.Z  | %s xvf -    # generates separate files\n",
  64.         decompressor, tar, tar;
  65.     printf "\n";
  66.     printf "and the job can be resubmitted using the following command:\n";
  67.     printf "\n";
  68.     printf "    sendfax -d %s" poll notify resopt "%s\n", number, files;
  69.     printf "\n";
  70.  
  71.     system("cd docq;" tar " cf - " files \
  72.             " | " compressor \
  73.             " | " encoder " rts." tar ".Z");
  74.     }
  75. }
  76.  
  77. func returnTranscript(pid, canon)
  78. {
  79.     system(transcript " " pid " \"" canon "\" 2>&1");
  80. }
  81.  
  82. func printStatus(s)
  83. {
  84.     if (s == "")
  85.     print "<no reason recorded>";
  86.     else
  87.     print s
  88. }
  89.  
  90. BEGIN        { nfiles = 0; }
  91. /^number/    { number = $2; }
  92. /^sender/    { sender = $2; }
  93. /^mailaddr/    { mailaddr = $2; }
  94. /^jobtag/    { jobtag = $2; }
  95. /^status/    { status = $2; }
  96. /^resolution/    { resolution = $2;
  97.           if (resolution == 196)
  98.               resopt = " -m";
  99.         }
  100. /^npages/    { npages = $2; }
  101. /^dirnum/    { dirnum = $2; }
  102. /^ntries/    { ntries = $2; }
  103. /^ndials/    { ndials = $2; }
  104. /^pagewidth/    { pagewidth = $2; }
  105. /^pagelength/    { pagelength = $2; }
  106. /^modem/    { modem = $2; }
  107. /^notify/    { if ($2 == "when done")
  108.               notify = " -D";
  109.           else if ($2 == "when requeued")
  110.               notify = " -R";
  111.         }
  112. /^sstatus/    { jstatus = $2; }
  113. /^[!]*post/    { split($2, parts, "/");
  114.           if (!match(parts[2], "\.cover")) {    # skip cover pages
  115.              files = files " " parts[2];
  116.              nfiles++;
  117.           }
  118.         }
  119. /^!tiff/    { split($2, parts, "/"); files = files " " parts[2]; nfiles++; }
  120. /^poll/        { poll = " -p"; }
  121. END {
  122.     if (jobtag == "")
  123.     jobtag = FILENAME;
  124.     print "To: " mailaddr;
  125.     print "Subject: notice about facsimile job " jobtag;
  126.     print "";
  127.     printf "Your facsimile job \"" jobtag "\" to \"" number "\"";
  128.     if (why == "done") {
  129.     print " was completed successfully.";
  130.     printf "Total transmission time was " jobTime ".";
  131.     if (status != "")
  132.         print "  Additional information:\n    " status;
  133.     } else if (why == "failed") {
  134.     printf " failed because:\n    ";
  135.     printStatus(status);
  136.     returnTranscript(pid, canon);
  137.     returnToSender();
  138.     } else if (why == "requeued") {
  139.     printf " was not sent because:\n    ";
  140.     printStatus(status);
  141.     print "";
  142.     print "The job will be retried at " nextTry "."
  143.     returnTranscript(pid, canon);
  144.     } else if (why == "removed" || why == "killed") {
  145.     print " was deleted from the queue.";
  146.     if (why == "killed")
  147.         returnToSender();
  148.     } else if (why == "timedout") {
  149.     print " could not be sent after repeated attempts.";
  150.     returnToSender();
  151.     } else if (why == "format_failed") {
  152.     print " was not sent because"
  153.     print "conversion of PostScript to facsimile failed.";
  154.     print "The output from \"" ps2fax "\" was:\n";
  155.     print status "\n";
  156.     printf "Check your job for non-standard fonts %s.\n",
  157.         "and invalid PostScript constructs";
  158.     returnToSender();
  159.     } else if (why == "no_formatter") {
  160.     print " was not sent because";
  161.     print "the conversion program \"" ps2fax "\" was not found.";
  162.     returnToSender();
  163.     } else if (match(why, "poll_*")) {
  164.     printf ", a polling request,\ncould not be completed because ";
  165.     if (why == "poll_rejected")
  166.         print "the remote side rejected your request.";
  167.     else if (why == "poll_no_document")
  168.         print "no document was available for retrieval.";
  169.     else if (why == "poll_failed")
  170.         print "an unspecified problem occurred.";
  171.     print "";
  172.     printf "Total connect time was %s.\n", jobTime;
  173.     } else if (why == "file_rejected") {
  174.     printf " was rejected because:\n    ";
  175.     printStatus(status);
  176.     returnToSender();
  177.     } else {
  178.     print " had something happen to it."
  179.     print "Unfortunately, the notification script was invoked",
  180.         "with an unknown reason"
  181.     print "so the rest of this message is for debugging:\n";
  182.     print "why: " why;
  183.     print "jobTime: " jobTime;
  184.     print "pid: " pid;
  185.     print "canon: " canon;
  186.     print "nextTry: " nextTry;
  187.     print  "";
  188.     print "This should not happen, please report it to your administrator.";
  189.     returnToSender();
  190.     }
  191. }
  192.